请注意，test same,same 完全等同于 cmp reg, 0，而且更小，所以它是编译器使用的.

Clang 的 版本比我的手写版本差很多.(请注意，它要求调用者将 bool 参数零扩展为 32 位，就像它对窄整数类型一样，作为它和 gcc 实现的 ABI 的非官方部分，但只有 clang 依赖于).

select:  # clang 6.0 trunk 317877 nightly build on Godbolt
    test    esi, esi
    cmove   edx, ecx         # x = b ? y : x
    test    edi, edi
    cmove   edx, ecx         # x = a ? y : x
    mov     eax, edx         # return x
    ret

gcc 8.0.0 20171110 nightly 为此制作分支代码，类似于旧版 gcc 所做的.

select(bool, bool, int, int):   # gcc 8.0.0-pre   20171110
    test    dil, dil
    mov     eax, edx          ; compiling with -mtune=intel or -mtune=haswell would keep test/jcc together for macro-fusion.
    je      .L8
    test    sil, sil
    je      .L8
    rep ret
.L8:
    mov     eax, ecx
    ret

MSVC x86-64 CL19 生成非常相似的分支代码.它针对 Windows 调用约定，其中整数 args 位于 rcx、rdx、r8、r9 中.

select PROC
        test     cl, cl         ; a
        je       SHORT $LN3@select
        mov      eax, r8d       ; retval = x
        test     dl, dl         ; b
        jne      SHORT $LN4@select
$LN3@select:
        mov      eax, r9d       ; retval = y
$LN4@select:
        ret      0              ; 0 means rsp += 0 after popping the return address, not C return 0.
                                ; MSVC doesn't emit the `ret imm16` opcode here, so IDK why they put an explicit 0 as an operand.
select ENDP

ICC18 也制作分支代码，但在分支之后有两个 mov 指令.

select(bool, bool, int, int):
        test      dil, dil                                      #8.13
        je        ..B4.4        # Prob 50%                      #8.13
        test      sil, sil                                      #8.16
        jne       ..B4.5        # Prob 50%                      #8.16
..B4.4:                         # Preds ..B4.2 ..B4.1
        mov       edx, ecx                                      #8.13
..B4.5:                         # Preds ..B4.2 ..B4.4
        mov       eax, edx                                      #8.13
        ret                                                     #8.13

试图帮助编译器使用

int select2(bool a, bool b, int x, int y) {
    bool ab = a&&b;
    return (ab) ? x : y;
}

导致 MSVC 编写非常糟糕的代码:

;; MSVC CL19  -Ox  = full optimization
select2 PROC
    test     cl, cl
    je       SHORT $LN3@select2
    test     dl, dl
    je       SHORT $LN3@select2
    mov      al, 1              ; ab = 1

    test     al, al             ;; and then test/cmov on an immediate constant!!!
    cmovne   r9d, r8d
    mov      eax, r9d
    ret      0
$LN3@select2:
    xor      al, al            ;; ab = 0

    test     al, al            ;; and then test/cmov on another path with known-constant condition.
    cmovne   r9d, r8d
    mov      eax, r9d
    ret      0
select2 ENDP

这仅适用于 MSVC(并且 ICC18 对刚刚设置为常量的寄存器上的 test/cmov 进行了相同的优化).

gcc 和 clang 像往常一样不会让代码像 MSVC 那样糟糕；他们为 select() 做同样的事情，这仍然不好，但至少尝试帮助他们不会像 MSVC 那样让事情变得更糟.

在我非常有限的测试中，| 和 & 似乎比 || 和 && 用于 MSVC 和 ICC.使用您的编译器 + 编译选项查看您自己代码的编译器输出，看看会发生什么.

int select_bitand(bool a, bool b, int x, int y) {
    return (a&b) ? x : y;
}

Gcc 仍然在两个输入的单独 test 上单独分支，代码与其他版本的 select 相同.clang 仍然执行两个单独的 test/cmov，与其他源版本的 asm 相同.

MSVC 通过并正确优化，击败了所有其他编译器(至少在独立定义中):

select_bitand PROC            ;; MSVC
    test     cl, dl           ;; ZF =  !(a & b)
    cmovne   r9d, r8d
    mov      eax, r9d         ;; could have done the mov to eax in parallel with the test, off the critical path, but close enough.
    ret      0

ICC18 浪费了两条 movzx 指令，将 bools 零扩展为 int，然后生成与 MSVC 相同的代码

select_bitand:          ## ICC18
    movzx     edi, dil                                      #16.49
    movzx     esi, sil                                      #16.49
    test      edi, esi                                      #17.15
    cmovne    ecx, edx                                      #17.15
    mov       eax, ecx                                      #17.15
    ret                                                     #17.15

这篇关于编译器中的 8 位布尔值.对它们的操作效率低吗?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持前端之家！