windows – 从xp中的批处理脚本中删除临时文件

我正在寻找一个很好的批处理脚本,可以快速找到&清除 Windows中所有已知的安全临时文件夹/文件(尽可能多的变体)计算机(例如Windows临时文件夹,所有用户IE临时文件夹等).我喜欢像CCleaner(通过Cleanmgr.exe)这样的UI工具,但是当我试图快速清理几台计算机和/或只需要很少的参与时,有一个脚本会很好.

再加上脚本,我可以将几个脚本链接在一起.也许一个人会启动各种防病毒和/或恶意软件检测器.

任何人都有一个好的或可以指向一个良好的资源？

这是我写的一个小脚本,我保留在我的USB实用程序驱动器上……对于Citrix服务器来说很棒:)

@echo off
Echo Started %time%
Echo Started %time% >> temps.txt
Echo Running for XP... >> temps.txt
Echo Running for XP...
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\Local Settings\Temp\" (
    RMDIR /S /Q "%%G\Local Settings\Temp"
    MKDIR "%%G\Local Settings\Temp"
    Echo Cleared %%G\Local Settings\Temp
    Echo Cleared %%G\Local Settings\Temp >> temps.txt
)
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\Local Settings\Temporary Internet Files\" (
    RMDIR /S /Q "%%G\Local Settings\Temporary Internet Files\"
    MKDIR "%%G\Local Settings\Temporary Internet Files\"
    Echo Cleared %%G\Local Settings\Temporary Internet Files\
    Echo Cleared %%G\Local Settings\Temporary Internet Files\ >> temps.txt
)
Echo Done.
Echo Running for Vista >> temps.txt
Echo Running for Vista...
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\AppData\Local\Temp\" (
    RMDIR /S /Q "%%G\AppData\Local\Temp\"
    MKDIR "%%G\AppData\Local\Temp\"
    Echo Cleared %%G\AppData\Local\Temp\
    Echo Cleared %%G\AppData\Local\Temp\ >> temps.txt
)
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\" (
    RMDIR /S /Q "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\"
    MKDIR "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\"
    Echo Cleared %%G\Local Settings\Temporary Internet Files\
    Echo Cleared %%G\Local Settings\Temporary Internet Files\ >> temps.txt
)
Echo Done.
Echo Ended %time%
Echo Ended %time% >> temps.txt

使用风险等等……这样可以解决问题.

我从Documents and Settings文件夹或Vista上的用户运行它.你可以轻松地将CD命令放在最上面,以便从任何你想要的地方运行它.

cd %userprofile%
cd ..

此外,根据我的经验,随时清除临时文件夹通常是安全的.使用temp中的文件的程序将锁定它们,并且该脚本将在该文件上出错并继续运行.

IF EXIST行在这里特别好用,它可以防止脚本在NetworkService和类似的文件夹中创建文件夹,如果你没有在Vista或XP上运行它,那么这个部分的速度非常快.

从哪里运行脚本创建temps.txt日志文件

编辑：Freenode上来自## windows-server的建议：问：为什么不在开始时检测它运行的操作系统并运行相应的部分？答：我经常在离线媒体上使用脚本,例如已经提取的硬盘.

windows – 从xp中的批处理脚本中删除临时文件

猜你在找的Windows相关文章