我正在尝试使用以下格式读取.ini文件:
- [SectionName]
- total=4
- [AnotherSectionName]
- total=7
- [OtherSectionName]
- total=12
基本上我想从.ini文件中打印出某些值,例如OtherSectionName下的总数,后跟AnotherSectionName中的总数.
这是一个命令文件(ini.cmd),可用于提取相关值:
- @setlocal enableextensions enabledelayedexpansion
- @echo off
- set file=%~1
- set area=[%~2]
- set key=%~3
- set currarea=
- for /f "usebackq delims=" %%a in ("!file!") do (
- set ln=%%a
- if "x!ln:~0,1!"=="x[" (
- set currarea=!ln!
- ) else (
- for /f "tokens=1,2 delims==" %%b in ("!ln!") do (
- set currkey=%%b
- set currval=%%c
- if "x!area!"=="x!currarea!" if "x!key!"=="x!currkey!" (
- echo !currval!
- )
- )
- )
- )
- endlocal
这里有一个成绩单显示它在行动(我手动缩进输出以使其更容易阅读):
- c:\src>type ini.ini
- [SectionName]
- total=4
- [AnotherSectionName]
- total=7
- [OtherSectionName]
- total=12
- c:\src>ini.cmd ini.ini SectionName total
- 4
- c:\src>ini.cmd ini.ini AnotherSectionName total
- 7
- c:\src>ini.cmd ini.ini OtherSectionName total
- 12
要在另一个cmd文件中实际使用它,只需将下面的echo%val%行替换为您要对其执行的操作):
- for /f "delims=" %%a in ('call ini.cmd ini.ini AnotherSectionName total') do (
- set val=%%a
- )
- echo %val%