通常，在CPS管道中使用groovy.util.slurpersupport.NodeChild（xml变量的类型）或groovy.util.slurpersupport.NodeChildren（xml.version的类型）是一个坏主意。这两个类均不可序列化，因此您无法在Groovy CPS中断言它们的行为。例如，我在Jenkins Pipeline中成功运行了您的第二个示例。很有可能是因为您提供的示例不完整或类似的东西。

groovy:000> xml = new XmlSlurper().parseText("<tag></tag>")
===> 
groovy:000> xml instanceof Serializable
===> false
groovy:000> xml.tag instanceof Serializable
===> false
groovy:000> xml.dump()
===> <groovy.util.slurpersupport.NodeChild@0 node=groovy.util.slurpersupport.Node@5b1f29fa parent= name=tag namespacePrefix=* namespaceMap=[xml:http://www.w3.org/XML/1998/namespace] namespaceTagHints=[xml:http://www.w3.org/XML/1998/namespace]>
groovy:000> xml.tag.dump()
===> <groovy.util.slurpersupport.NodeChildren@0 size=-1 parent= name=tag namespacePrefix=* namespaceMap=[xml:http://www.w3.org/XML/1998/namespace] namespaceTagHints=[xml:http://www.w3.org/XML/1998/namespace]>
groovy:000> 

如果要读取pom.xml文件，请使用readMavenPom管道步骤。它专用于读取pom文件以及最重要的内容-无需应用任何变通办法即可安全地进行读取。 pipeline-utility-steps plugin附带了这一步骤。

但是，如果由于某些原因要使用XmlSlurper，则需要在用@NonCPS注释的方法中使用它。这样，您可以访问“纯” Groovy并避免遇到的问题。 （但仍使用readMavenPom是实现您要尝试的操作的最安全方法。）此处的要点是使用@NonCPS范围内的所有不可序列化的对象，因此管道不会尝试序列化它。

下面您可以找到显示两种方法的简单管道示例。

pipeline {
    agent any 

    stages {
        stage("Using readMavenPom") {
            steps {
                script {
                    def xmlfile = readMavenPom file: "pom.xml"
                    def version = xmlfile.version
                    echo "version = ${version}"
                }
            }
        }

        stage("Using XmlSlurper") {
            steps {
                script {
                    def xmlfile = readFile "pom.xml"
                    def version = extractFromXml(xmlfile) { xml -> xml.version }
                    echo "version = ${version}"
                }
            }
        }
    }
}

@NonCPS
String extractFromXml(String xml,Closure closure) {
    def node = new XmlSlurper().parseText(xml)
    return closure.call(node)?.text()
}

PS：更不用说使用XmlSlurper至少需要获得脚本3的批准，然后才能开始使用它。