一个例子：

SQL> CREATE OR REPLACE PROCEDURE testException
  2  IS
  3  BEGIN
  4      raise INVALID_ID;
  5  EXCEPTION
  6      WHEN INVALID_ID THEN
  7          dbms_output.put_line('Invalid ID');
  8  END;
  9  /

Warning: Procedure created with compilation errors.

一种了解错误的方法：

SQL> sho err
Errors for PROCEDURE TESTEXCEPTION:

LINE/COL ERROR
-------- -----------------------------------------------------------------
0/0      PL/SQL: Compilation unit analysis terminated
4/5      PL/SQL: Statement ignored
4/11     PLS-00201: identifier 'INVALID_ID' must be declared
6/10     PLS-00201: identifier 'INVALID_ID' must be declared

您需要声明使用的异常：

SQL> CREATE OR REPLACE PROCEDURE testException
  2  IS
  3      INVALID_ID exception;
  4  BEGIN
  5      raise INVALID_ID;
  6  EXCEPTION
  7      WHEN INVALID_ID THEN
  8          dbms_output.put_line('Invalid ID');
  9  END;
 10  /

Procedure created.

在此DEMO中，您将看到此过程应处理的所有3种情况：

这是正确的过程：

CREATE OR REPLACE PROCEDURE raise_salary
(eid IN employees.e_id%TYPE,raise IN employees.salary%type)
IS

cnt INTEGER;
sal employees.salary%TYPE;
INVALID_ID exception;
NULL_VALUE exception;

BEGIN

 SELECT count(*) 
 INTO cnt 
 FROM employees 
 WHERE e_id=eid;

 IF cnt=0 THEN
     RAISE INVALID_ID;
 ELSE    
     SELECT salary 
     INTO sal 
     FROM employees 
     WHERE e_id=eid;

     IF sal IS NULL THEN
            RAISE NULL_VALUE;
        ELSE
            UPDATE employees 
            SET salary = (SAL + raise)
            WHERE e_id = eid;

            dbms_output.put_line('Salary raised!');
     END IF;    
 END IF;

exception
 WHEN INVALID_ID THEN
     dbms_output.put_line('User ID does not exist!');
 WHEN NULL_VALUE THEN
     dbms_output.put_line('Salary is null in table!');
 WHEN others THEN
     dbms_output.put_line('Error!');
END;
/

您有多个错误，@ Aleksej在他的回答VOTE UP中很好地解释了一个错误。 您也有一行：

SELECT salary INTO sal FROM employees WHERE e_id=eid;

但是您尚未宣布萨尔。 希望这会有所帮助...